GetWindowNavigator()

//******************************************************************************
// - Funktion erstellt im Fenster-Navigator eine "eigene Oberfläche", die
//   bisherige Oberfläche wird überblendet.
// - Angezeigt wird ein Browser und ein RichMemo, darin wird die
//   Standard-Tabelle "Textbausteine" (Workarea 12) geladen.
// - Diese Funktion kann aus einem beliebigen Kontext aufgerufen werden
//   (z.B. individueller Menüpunkt). Funktioniert nur in Fenstern, in denen der
//   Fenster-Navigator auch im Standard zur Verfügung steht.
//******************************************************************************
function SwitchNavigatorVisible()
| oDockPanel, oWN, oNavigPanel, oMyForm, oRichMemo, oGrid, oTable, oDataSource |
   oWN := GetWindowNavigator(),
   if not empty(oWN) then
      oDockPanel := FindObject(oWN, 'WINDOW_NAVIG_DOCK_PANEL'),
      if not empty(oDockPanel) then
         oNavigPanel := FindObject(oWN, 'WINDOW_NAVIG_PANEL'),
         if not empty(oNavigPanel) then
            startseq,
               oMyForm := FindObject(oDockPanel, 'MYFORM'),
               if empty(oMyForm) then
                  oMyForm               := CreateObject('TFormEx', 'MYFORM', oDockPanel, oDockPanel),
                  oMyForm.Align         := alCLient,
                  oMyForm.BorderStyle   := bsNone,

                  oTable                := DbGetTable(gl_odm, waDAB350),

                  oDataSource           := CreateObject('TDataSourceEx', , oMyForm, oMyForm),
                  oDataSource.DataSet   := oTable,

                  oGrid                 := CreateObject('TBeAltGrid', , oMyForm, oMyForm),
                  oGrid.Align           := alBottom,
                  oGrid.Height          := 200,
                  oGrid.DataSource      := oDataSource,
                  oGrid.RegisterDataSet := oTable,
                  oGrid.ID              := '@HINTXT',
                  oGrid.ReadWriteProps  := false,

                  oRichMemo             := CreateObject('TBeRichEditEx', , oMyForm, oMyForm),
                  oRichMemo.Align       := alClient,
                  oRichMemo.DataSource  := oDataSource,
                  oRichMemo.DataField   := 'MEMO',
                  Show(oMyForm), // erstes Anzeigen des Forms sollte immer im Show() laufen
               endif,

               // Sichtbarkeit umschalten
               oMyForm.Visible := not oMyForm.Visible,

            onerror,
               MessageDlg('Fehler beim Anzeigen des eigenen Navigators: ' + crlf +
                          GetErrorText(), mtError),
            stopseq,
         endif,
      endif,
   endif,
end,

SwitchNavigatorVisible(),