TBeProductionPartListBO

//##############################################################################
//##############################################################################
// Beschreibung: Kleines Testprogramm für die Funktionalität
//               des BeProductionPartListBusinessObject
// Hinweis:      Aktuell nur Read-Only!
//##############################################################################
//##############################################################################

|
   oDab240, oProductionPartListBO, m_cFirstArtNr, m_cSecondArtNr,
   m_cFirstB_Pos_LfdNo, m_cSecondB_Pos_LfdNo
|

//##############################################################################
//##############################################################################
// Konstanten
//##############################################################################
//##############################################################################

m_cFirstArtNr        := 'TESTART1',
m_cSecondArtNr       := 'TESTART2',

m_cFirstB_Pos_LfdNo  := '123666 321',
m_cSecondB_Pos_LfdNo := '123666 322',

//##############################################################################
//##############################################################################
// Funktionen
//##############################################################################
//##############################################################################

//******************************************************************************
// Erstellen
//******************************************************************************
function WriteProductionPosition()
   BeginSuspend(oDab240),
   startseq
      DBAppend(oDab240),
      oDab240:ARTNR1    := m_cFirstArtNr,
      oDab240:B_POS_LFD := m_cFirstB_Pos_LfdNo,
      DBPost(oDab240),

      DBAppend(oDab240),
      oDab240:ARTNR1    := m_cSecondArtNr,
      oDab240:B_POS_LFD := m_cSecondB_Pos_LfdNo,
      DBPost(oDab240),
   always
      EndSuspend(oDab240),
   stopseq,
end,

//******************************************************************************
// Löschen
//******************************************************************************
function DeleteProductionPosition()
   BeginSuspend(oDab240),
   startseq
      DBGoTo(m_cFirstB_Pos_LfdNo, oDab240),
      DBDelete(oDab240),

      DBGoTo(m_cSecondB_Pos_LfdNo, oDab240),
      DBDelete(oDab240),
   always
      EndSuspend(oDab240),
   stopseq,
end,

//******************************************************************************
// Objekte erstellen
//******************************************************************************
function GetObjects()
   oDab240               := DBOpen(waDab240),
   oProductionPartListBO := CreateObject("TBeProductionPartListBO"),
end,

//******************************************************************************
// Objekte freigeben
//******************************************************************************
function DestroyObjects()
   DeleteProductionPosition(),
   DestroyObject(oDab240),
   DestroyObject(oProductionPartListBO),
end,

//##############################################################################
//##############################################################################
// Hauptprogramm
//##############################################################################
//##############################################################################

startseq
   GetObjects(),
   startseq
      // Zwei Einträge erstellen und Überprüfen ...
      WriteProductionPosition(),
      oProductionPartListBO.CbGoToProdOrderPosNo(m_cFirstB_Pos_LfdNo),
      if (oProductionPartListBO.CbMainArticleNo = m_cFirstArtNr) and
         (oProductionPartListBO.CbMainArticleNo <> m_cSecondArtNr) then
         WriteLn("Testartikel 1 mit der Artikel-Nummer" + CRLF +
                 oProductionPartListBO.CbMainArticleNo + CRLF +
                 "gefunden!"),
      endif,

      oProductionPartListBO.CbGoToProdOrderPosNo(m_cSecondB_Pos_LfdNo),
      if (oProductionPartListBO.CbMainArticleNo <> m_cFirstArtNr) and
         (oProductionPartListBO.CbMainArticleNo = m_cSecondArtNr) then
         WriteLn("Testartikel 2 mit der Artikel-Nummer" + CRLF +
                 oProductionPartListBO.CbMainArticleNo + CRLF +
                 "gefunden!"),
      endif,
   always
      // Einträge wieder löschen
      DestroyObjects(),
   stopseq,
onerror
   MessageDlg('Fehler im Programm ' + ProgName() + crlf +
              GetErrorText() + crlf + crlf +
              DebugArr(GetErrorStack(true)), mtError),
stopseq,