TBeBarManager

Komponente zum Steuern von Toolbarelementen.
Funktionen und Methoden	Beschreibung
CbAddToolbar():	Erzeugt eine TbeBar
CbDeleteToolBar(oBar:O)	Löscht eine erzeugte TbeBar
CbBeginUpdate()	Verhindert Aktualisierung und Neuzeichnen
CbEndUpdate()	Erlaubt Aktualisierung und Neuzeichnen
Beispiel

CODE
//##############################################################################
//##############################################################################
// Online-Hilfe Beispiel für die Klasse 'TBeBarManager'
//##############################################################################
//##############################################################################

| oBarManager, oForm, oBar, btn_BarButton1, pnl_Main, oActionList, aActionButton1 |

//##############################################################################
//##############################################################################
// Eventhandler
//##############################################################################
//##############################################################################


//******************************************************************************
//
// @Result: null
//******************************************************************************
function A_DeleteToolbar  ( Sender )
   startseq,
     oBarManager.CbDeleteToolBar(oBar),
   onerror
      GU_ShowStdErrorMessage(GetErrorText(), GetErrorObj()),
   stopseq,
end,

//******************************************************************************
// InitForm lädt das Formular
// @Result: null
//******************************************************************************
function InitForm()
   oForm             := CreateObject('TFormEx', 'TFormEx'),
   oForm.BorderStyle := bsSingle,
   oForm.Width       := 500,
   oForm.Height      := 500,
   oForm.OrigCapt    := 'Beispielprogramm',
   oForm.Position    := poScreenCenter,
end,

//******************************************************************************
// LoadGUI lädt sämtliche Komponenten die für die Oberfläche benötigt werden
// @Result: null
//******************************************************************************
function LoadGUID()
   pnl_Main         := CreateObject('TBePanel', 'Main', oForm, oForm),
   pnl_Main.Align   := alClient,
   pnl_Main.Caption := '',

   oBarManager        := CreateObject('TBeBarManager', 'barMan', oForm),
   oBarManager.Images := BeImageList(nImageListMain16),
   oBar               := oBarManager.CbAddToolbar(),

   oActionList        := createObject('TBeActionList', 'actions', oForm, oForm),
   oActionList.Images := BeImageList(nImageListMain16),

   aActionButton1            := CreateObject('TBeAction', 'A_DeleteToolbar', oForm, oForm),
   aActionButton1.ActionList := oActionList,
   aActionButton1.Caption    := 'Delete Toolbar',
   aActionButton1.ImageIndex := 928,

   btn_BarButton1            := oBar.CbAddButton(),
   btn_BarButton1.Action     := aActionButton1,
   btn_BarButton1.PaintStyle := psCaptionGlyph,
   AssignEvent(aActionButton1, 'OnExecute', 'A_DeleteToolbar'),
end,


//##############################################################################
//##############################################################################
// Hauptprogramm
//##############################################################################
//##############################################################################
startseq,
   InitForm(),
   LoadGUID(),
   ShowModal(oForm),

   DestroyObject(oBarManager),
   DestroyObject(oActionList),
onerror
   DestroyObject(oBarManager),
   DestroyObject(oActionList),
   DestroyObject(oForm),
   GU_ShowStdErrorMessage(GetErrorText(), GetErrorObj()),
stopseq,
Weitere Verknüpfungen

TBeBar