Event "Telefonie - nach Erstellen eines Anzeige-Panels"

Dieser Event wird aufgerufen, nachdem durch einen eingehenden Anruf ein Anzeige-Panel in der be - Anruferliste erstellt wurde.
Über den Parameter nCallType kann die Art des Anruferlisten-Eintrags ermittelt werden.
Mögliche Werte von nCallType sind:
0 - alter eingehender Anruf
1 - neuer eingehender Anruf (Eintrag hat farbliche Hervorhebung im Anruferlisten-Dialog)
2 - automatischer Rückruf
3 - Ruf-Erinnerung

Beispiel

CODE

| nEvtNo:P1, cTelNummer:P2, oPanel:P3, aElement:P4, oDab000:P5, oDab100:P6, oDab062:P7,   oDab005:P8, nCallType:P9 |

// aElement - {Typ, Kd/Z/V.Nummer, Kontakt-ID}
// Es können beliebige Eigenschaften von oPanel verändert werden (z.B. Größe, Farbe, Schrift, Caption)
// und auch neue Controls mit oPanel als Parent erstellt werden (z.B. ein Rückruf-Button)


//******************************************************************************
// erzeugt einen Button auf dem TAPI-Panel für Demo-Zwecke
//*****************************************************************************<h3>
function CreateDemoButton()
  | oParent, myNewButton, cCodeBlock |
   oParent := GetParentForm(oPanel),
   if not empty(oParent) then
      prs('', ClassName(oParent) + '/' + oParent.Name),

      // den Button nur dann erzeugen, wenn es sich um ein Panel mit Kontaktperson-Bezug handelt
      if (not empty(aElement)) and (aElement[3] <> 0) then // Inahalt von aElement ist z.B. {"V", 999, 86276}
         myNewButton := CreateObject('TBeBlockBtn',, oPanel, oPanel),
         myNewButton.ImageIndex.IndexNormal := 642,

         // Button dynamisch rechts ausrichten 
         myNewButton.Width  := 66,
         myNewButton.Align  := alRight,
         myNewButton.AlignWithMargins := True,
         myNewButton.Margins.Top    := 1,
         myNewButton.Margins.Left   := 1,
         myNewButton.Margins.Right  := 5,
         myNewButton.Margins.Bottom := 0,

         myNewButton.Caption    := 'Demo',
         myNewButton.Hint       := 'dieser Knopf demonstriert den Einsatz des Events ' + crlf + crlf +
                                   '"Telefonie - nach Erstellen eines Anzeige-Panels"',
         myNewButton.ShowHint   := True,
         myNewButton.Font.Name  := 'Arial',
         myNewButton.Font.Style := myNewButton.Font.Style + 3,

         cCodeBlock := "MessageDlg(lookup(waDAB005, 'DAB008', {{" + Str(aElement[3]) + "}}, 'NAME', 'FEHLER'))",

         myNewButton.BlockStr := cCodeBlock,
      endif,

   endif,
end,

//##############################################################################
// Hauptprogramm
//##############################################################################

startseq,
   CreateDemoButton(),
onerror,
   MessageDlg('Es ist ein Fehler im Programm "Telefonie - nach Erstellen eines Anzeige-Panels" aufgetreten: '
              + crlf + crlf + GetErrorText(), mtError),
stopseq,

Weitere Verknüpfungen

Event "Telefonie - vor Auswertung des Anrufes"
Event "Telefonie - bei Klick auf ein Anzeige-Panel"
Event "Telefonie - nach Auswertung des Anrufes"