Event "beim Laden einer Browser-Definition"

//##############################################################################
//##############################################################################
// Beschreibung
// Dieser Event wird zu Beginn des Laden der Browser-Definition aufgerufen.
// Durch den Event kann die standardmäßige Definition des Browsers übersteuert werden.
//
// Verwendungsmöglichkeiten:
// - CbUserNo und/oder CbBrowserID verändern, damit wird der entsprechend andere Datensatz aus der DabBRO gelesen
// - CbUseData setzen und in den CbBrowserData die gesamte Browserdefinition als String angeben, durch z.B. Einlesen der
//   entsprechenden BEB-Datei
//
// In beiden Fällen hat die Browser-Definition, die für den User und die BrowserID des Event-Aufrufs in der DabBRO
// gespeichert sind, keine Wirkung mehr.
// Mit dem Flag CbDoNotStoreBrowser kann verhindert werden, dass DabBRO-Datensätze angelegt/gespeichert werden, somit
// werden Browser-Änderungen nicht mehr gespeichert.
//
// Bleibt der Inhalt der Parameter unverändert, erfolgt das Laden der Browser-Definition wie bisher.
//
// Hinweis
// - beim Laden der Default-Einstellungen wird der Event mit CbUserNo = 0 aufgerufen. Zusätzlich ist das Flag CbLoadDefaults auf True gesetzt.
// - Werden die Daten vom Event geliefert (CbBrowserData <> '' und CbUseData), wird keine Übersetzung der Browser-Überschriften ausgeführt.
// - Werden CbUserNo und/oder CbBrowserID verändert, bezieht sich die Übersetzung der Browser-Überschriften auf die geänderten Werte.
//
// Parameter
// - nEventNo: integer               - Nummer des Events
// - oParams: TBeCbLoadBrowserParam  - Parameter-Objekt zur Steuerung des Events
//
//   Eigenschaften (nur lesen)
//   - CbDefaultsLoading: boolean    - Flag, ob der Event beim Laden der Defaults aufgerufen wird
//
//   Eigenschaften (lesen und schreiben)
//   - CbBrowserID: string           - ID des Browsers, dessen Datensatz aus der DabBRO gelesen werden soll
//   - CbUserNo: integer             - UserNo, dessen Datensatz aus der DabBRO gelesen werden soll
//
//   Eigenschaften (nur schreiben)
//   - CbBrowserData: string         - alternativ zum Lesen der Browser-Daten aus der DabBRO kann hier
//                                     die komplette Definition angegeben werden.
//   - CbUseData: boolean            - muss auf True gesetzt werden damit die Browser-Daten aus CbBrowserData verwendet werden.
//   - CbDoNotStoreBrowser: boolean  - dieses Flag steuert, ob für die ursprüngliche BrowserID und UserNo,
//                                     die Daten in der DabBRO gespeichert werden soll.
//
//##############################################################################
//##############################################################################
|
   nEventNo:P1, oParams:P2
   , cPath, cFileName
|

//***** verschiedene Beispiele zur Nutzung des Events ************

// Browser durch Individual-Browser ersetzen
// in der DabBRO wird die Definition aber unter dem Original-Browser-ID gespeichert
if oParams.CbBrowserID = 'StoreFi   ' then
   oParams.CbBrowserID := '@StoreFi  ',
endif,

// immer die Defaults laden und kein Speichern in DabBRO
if (oParams.CbBrowserID = 'SUP_DI  ') then
   if not oParams.CbDefaultsLoading then
      oParams.CbDoNotStoreBrowser := True,
   endif,
   oParams.CbUserNo := 0,
endif,

// Browser-Definition aus Datei laden
if oParams.CbUserNo = 65 then
   cPath               := mbedefault,
   cFilename           := cPath + Trim(oParams.CbBrowserID) + '.BEB',
   if File(cFilename) then
      oParams.CbBrowserData       := MemoRead(cFilename),
      oParams.CbUseData           := (oParams.CbBrowserData <> ''),
      oParams.CbDoNotStoreBrowser :=  oParams.CbUseData,
   endif,
endif,